%# BEGIN BPS TAGGED BLOCK {{{
%#
%# COPYRIGHT:
%#
%# This software is Copyright (c) 1996-2025 Best Practical Solutions, LLC
%#                                          <sales@bestpractical.com>
%#
%# (Except where explicitly superseded by other copyright notices)
%#
%#
%# LICENSE:
%#
%# This work is made available to you under the terms of Version 2 of
%# the GNU General Public License. A copy of that license should have
%# been provided with this software, but in any event can be snarfed
%# from www.gnu.org.
%#
%# This work is distributed in the hope that it will be useful, but
%# WITHOUT ANY WARRANTY; without even the implied warranty of
%# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
%# General Public License for more details.
%#
%# You should have received a copy of the GNU General Public License
%# along with this program; if not, write to the Free Software
%# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
%# 02110-1301 or visit their web page on the internet at
%# http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
%#
%#
%# CONTRIBUTION SUBMISSION POLICY:
%#
%# (The following paragraph is not intended to limit the rights granted
%# to you to modify and distribute this software under the terms of
%# the GNU General Public License and is only of importance to you if
%# you choose to contribute your changes and enhancements to the
%# community by submitting them to Best Practical Solutions, LLC.)
%#
%# By intentionally submitting any modifications, corrections or
%# derivatives to this work, or any other work intended for use with
%# Request Tracker, to Best Practical Solutions, LLC, you confirm that
%# you are the copyright holder for those contributions and you grant
%# Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
%# royalty-free, perpetual, license to use, copy, create derivative
%# works based on those contributions, and sublicense and distribute
%# those contributions and any derivatives thereof.
%#
%# END BPS TAGGED BLOCK }}}
<& /Views/Component/QuickCalls, From => $ARGS{From} &>
% $m->abort; # No footer
<%init>
if ( $QuickCall ) {
    my $config = RT->Config->Get('QuickCalls');
    my $quickcalls;

    if ( ref $config eq 'ARRAY' ) {
        # old behavior
        $quickcalls = $config;
    }
    elsif ( ref $config eq 'HASH' ) {
        # new behavior
        my $quickcall_dashboard_id = $ARGS{QuickCallsDashboard} || '';
        my $quickcall_config = $config->{$quickcall_dashboard_id} || $config->{Default} || {};
        $quickcalls = $quickcall_config->{Actions} || [];
    }

    if ( my ( $QuickCall ) = grep { $_->{Name} eq $QuickCall } @$quickcalls ) {
        # copy so we don't nuke the config variable
        $QuickCall = { map { $_ => $QuickCall->{$_} } keys %$QuickCall };
        $QuickCall->{Subject} ||= $QuickCall->{Name};
        $QuickCall->{Owner} = $session{CurrentUser}->Id
            if ( $QuickCall->{SetOwnerToCurrentUser} );

        delete $QuickCall->{SetOwnerToCurrentUser};
        delete $QuickCall->{Name};

        # Anon subrefs can be used to generate dynamic values
        $QuickCall->{$_} = $QuickCall->{$_}->()
            for grep { ref $QuickCall->{$_} eq "CODE" } keys %{$QuickCall};

        if ( $QuickCall->{QuickCreate} ) {
            my @results;
            push @results, ProcessQuickCreate(
                ARGSRef => $QuickCall,
                $ARGS{PassArguments}
                ? (
                    PassArguments => {
                        map { $_ => $ARGS{$_} } ref $ARGS{PassArguments} eq 'ARRAY' ? @{ $ARGS{PassArguments} } : $ARGS{PassArguments}
                    },
                )
                : (),
            );
            $r->headers_out->{'HX-Trigger'} = JSON(
                {
                    actionsChanged => \@results
                },
                ascii => 1,
            ) if @results;
        }
        else {
            my $query = $m->comp( '/Elements/QueryString', %$QuickCall );
            RT::Interface::Web::Redirect( $RT::WebURL . "Ticket/Create.html?$query" );
        }
    }
}
</%init>
<%args>
$QuickCall => undef
</%args>
